set term pngcairo size 1024,768 background rgb '#ffffee'
  set output '| ffmpeg -y -r 15 -f image2pipe -i - -vcodec libx264 -profile:v baseline -pix_fmt yuv420p slab.mp4'
# set output 'slab.png'
  set colors classic
  set encoding utf8
  set minussign

  TimeBetSnapshot = 0.1
  gamma = 5./3.
  pressure(rho,U) = (gamma-1.)*rho*U
  energy(rho,U,vx,vy,vz,Bx,By,Bz) = U*rho + 0.5*(Bx**2+By**2+Bz**2) + 0.5*rho*(vx**2+vy**2+vz**2)

  unset key
  set tics front
  set grid lt 7 lc rgb '#eeeeee'
  set object rectangle from graph 0,0 to graph 1,1 fs solid noborder fc rgb 'white' behind

# We set all margins to zero and position the plots manually instead.
  set lmargin 0
  set tmargin 0
  set bmargin 0
  set rmargin 0
  set size 0.24,0.26
  x0 = 0.09
  dx = 0.32
  y0 = 0.10
  dy = 0.28

  set xrange [25:75]

  n = 60
  do for [i=0:n] {
    filename=sprintf('output_%03d.txt',i)
    print filename
    t = i*TimeBetSnapshot
    lbl = sprintf('t = %3.1f',t)
    set multiplot

    unset xlabel
    set format x ''
    set label lbl at screen 0.5,1 offset 0,-1.5 font 'Helvetica-Bold'

    set ylabel 'density' offset 0,0
    set yrange [0:1.2]
    set origin x0+0*dx,y0+2*dy
    plot \
      filename u 6:4 w d

    unset label

    set ylabel 'pressure'
    set yrange [0:1.2]
    set origin x0+1*dx,y0+2*dy
    plot \
      filename u 6:(pressure($4,$5)) w d

    set ylabel 'energy'
    set yrange [0:2.5]
    set origin x0+2*dx,y0+2*dy
    plot \
      filename u 6:(energy($4,$5,$9,$10,$11,$12,$13,$14)) w d

    set ylabel 'v_x' offset 1,0
    set yrange [-1.8:1.8]
    set origin x0+0*dx,y0+1*dy
    plot \
      filename u 6:9 w d

    set ylabel 'v_y'
    set yrange [-1.8:1.8]
    set origin x0+1*dx,y0+1*dy
    plot \
      filename u 6:10 w d

    set ylabel 'v_z'
    set yrange [-1.8:1.8]
    set origin x0+2*dx,y0+1*dy
    plot \
      filename u 6:11 w d

    set xlabel 'x'
    set format x '%g'

    set ylabel 'B_x'
    set yrange [-1.2:1.2]
    set origin x0+0*dx,y0+0*dy
    plot \
      filename u 6:12 w d

    set ylabel 'B_y'
    set yrange [-1.2:1.2]
    set origin x0+1*dx,y0+0*dy
    plot \
      filename u 6:13 w d

    set ylabel 'B_z'
    set yrange [-1.2:1.2]
    set origin x0+2*dx,y0+0*dy
    plot \
      filename u 6:14 w d

    unset multiplot
  }